{
  description = "srid/haskell-template: Nix template for Haskell projects";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    systems.url = "github:nix-systems/default";
    flake-parts.url = "github:hercules-ci/flake-parts";
    haskell-flake.url = "github:srid/haskell-flake";
    flake-root.url = "github:srid/flake-root";
    treefmt-nix.url = "github:numtide/treefmt-nix";
    treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";
    mission-control.url = "github:Platonic-Systems/mission-control";

    winery = {
      url = "github:fumieval/winery";
      flake = false;
    };

    barbies-th = {
      url = "github:fumieval/barbies-th";
      flake = false;
    };


    barbies = {
      url = "github:jcpetruzza/barbies";
      flake = false;
    };

  };

  outputs = inputs:
  inputs.flake-parts.lib.mkFlake { inherit inputs; } {
    systems = import inputs.systems;
    imports = [
      inputs.flake-root.flakeModule
      inputs.haskell-flake.flakeModule
      inputs.treefmt-nix.flakeModule
      inputs.mission-control.flakeModule
    ];
    perSystem = { self', system, lib, config, pkgs, ... }: {
      # Our only Haskell project. You can have multiple projects, but this template
      # has only one.
      # See https://github.com/srid/haskell-flake/blob/master/example/flake.nix
      haskellProjects.default = {
        # The base package set (this value is the default)
        # basePackages = pkgs.haskell.packages.ghc910;

        # Packages to add on top of `basePackages`
        packages = {
          # Add source or Hackage overrides here
          # (Local packages are added automatically)
          # https://github.com/lehins/hip.git
          # hip.source = inputs.hip + "/hip";
          winery.source = inputs.winery;
          barbies-th.source = inputs.barbies-th;
          barbies.source = inputs.barbies;
        };

        # Add your package overrides here
        settings = {
          uuid.jailbreak = true;
          # accelerate =
          #   {
          #     jailbreak = true;
          #     broken = false;
          #   };
          # winery.broken = false;
          winery.jailbreak = true;
          winery.check = false;
          barbies-th.broken = false;
          barbies-th.jailbreak = true;
          barbies.broken = false;
          barbies.jailbreak = true;
          barbies.check = false;
          tree-diff.check = false;
          # hlint.jailbreak = true;
          # ghc-lib-parser.jailbreak = true;
          # ghc-lib-parser-ex.jailbreak = true;
          # gmp-with-cxx.jailbreak = true;
        };
        # hlint = {
          #   jailbreak = true;
          # };
          # barbies-th = {
            #   broken = false;
            #   jailbreak = true;
            # };

            # Development shell configuration
            devShell = {
              hlsCheck.enable = true;
            };

            # What should haskell-flake add to flake outputs?
            autoWire = [ "packages" "apps" "checks" ]; # Wire all but the devShell
      };

      # Auto formatters. This also adds a flake check to ensure that the
      # source tree was auto formatted.
      treefmt.config = {
        projectRootFile = "flake.nix";

        programs.ormolu.enable = true;
        programs.nixpkgs-fmt.enable = true;
        programs.cabal-fmt.enable = true;
        # programs.hlint.enable = false;

        # We use fourmolu
        programs.ormolu.package = pkgs.haskellPackages.fourmolu;
      };

      # Default package & app.
      packages.default = self'.packages.compress;
      apps.default = self'.apps.compress;

      mission-control.scripts = {
          hoogle = {
            description = "Start Hoogle server for project dependencies";
            exec = ''
              hoogle serve -p 8888 --local;
            '';
            category = "Dev Tools";
          };

          haddocks = {
            description = "make docs & serve them";
            exec = ''
              echo http://127.0.0.1:8887;
              cabal haddock-project --executables --internal --hoogle || true;
              python3 -m http.server -d haddocks 8887;
            '';
            category = "Dev Tools";
          };

        };

      # Default shell.
      devShells.default = pkgs.mkShell {
        name = "haskell-template";
        meta.description = "Haskell development environment";
        # See https://zero-to-flakes.com/haskell-flake/devshell#composing-devshells
        inputsFrom = [
          config.mission-control.devShell
          config.haskellProjects.default.outputs.devShell
          config.treefmt.build.devShell
        ];
        nativeBuildInputs = with pkgs; [
          # llvmPackages_16.libllvm
        ];
      };
    };
  };
}